pro/TaskList_Demo.pro - master - waterstone/TaskList_Demo

pro/TaskList_Demo.pro
80 строк2 KB
Peter Sakhno
Move TaskWatcher from the model module to a saparete module
21 янв 2026, 18:10
21 янв 2026, 18:10ef15936
QT       += core gui concurrent

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17

##--------------------------
## Defines
##--------------------------
APP_PROJ_ROOT = ..
APP_SRC_DIR   = $${APP_PROJ_ROOT}/src
APP_RES_DIR   = $${APP_PROJ_ROOT}/res
APP_LOC_DIR   = $${APP_PROJ_ROOT}/loc
APP_BIN_DIR   = $${APP_PROJ_ROOT}/bin
APP_OUT_DIR   = $${APP_PROJ_ROOT}/out

CONFIG_SUFFIX_STR   = release
CONFIG(debug, debug|release) {
  CONFIG_SUFFIX_STR = debug
  APP_BIN_DIR       = $${APP_BIN_DIR}d
}

##--------------------------
## Sources
##--------------------------

INCLUDEPATH += \
    $${APP_SRC_DIR}

SOURCES += \
    $${APP_SRC_DIR}/main.cpp \
    $${APP_SRC_DIR}/tasklist_main_view.cpp \
    $${APP_SRC_DIR}/tasklist_table_model.cpp \
    $${APP_SRC_DIR}/tasklist_proxy_table_model.cpp \
    $${APP_SRC_DIR}/tasklist_action_cell_delegate.cpp \
    $${APP_SRC_DIR}/tasklist_progress_cell_delegate.cpp 

HEADERS += \
    $${APP_SRC_DIR}/task_watcher.h \
    $${APP_SRC_DIR}/tasklist_ranges.h \
    $${APP_SRC_DIR}/tasklist_main_view.h \
    $${APP_SRC_DIR}/tasklist_table_model.h \
    $${APP_SRC_DIR}/tasklist_proxy_table_model.h \
    $${APP_SRC_DIR}/tasklist_action_cell_delegate.h \
    $${APP_SRC_DIR}/tasklist_progress_cell_delegate.h

FORMS += \
    $${APP_SRC_DIR}/tasklist_main_view.ui

##--------------------------
## Resources
##--------------------------

RESOURCES += \
    $${APP_RES_DIR}/res.qrc

##--------------------------
## Translations
##--------------------------

TRANSLATIONS += \
    $${APP_LOC_DIR}/tasklist_ru_RU.ts
#CONFIG += lrelease
#CONFIG += embed_translations
exists($${APP_LOC_DIR}/tasklist_ru_RU.qm) {
  exists($${APP_LOC_DIR}/qm_files.qrc) {
    RESOURCES += \
        $${APP_LOC_DIR}/qm_files.qrc
  }
}

##--------------------------
## Build config
##--------------------------

UI_DIR              = $${APP_OUT_DIR}/ui_files
RCC_DIR             = $${APP_OUT_DIR}/rcc_files
DESTDIR             = $${APP_BIN_DIR}
OBJECTS_DIR         = $${APP_OUT_DIR}/$${CONFIG_SUFFIX_STR}
MOC_DIR             = $${APP_OUT_DIR}/$${CONFIG_SUFFIX_STR}