qemu

1
/*
2
 * Linker script for linux aarch64 replacement vdso.
3
 *
4
 * Copyright 2021 Linaro, Ltd.
5
 *
6
 * SPDX-License-Identifier: GPL-2.0-or-later
7
 */
8

9
VERSION {
10
        LINUX_2.6.39 {
11
        global:
12
                __kernel_rt_sigreturn;
13
                __kernel_gettimeofday;
14
                __kernel_clock_gettime;
15
                __kernel_clock_getres;
16

17
        local: *;
18
        };
19
}
20

21

22
PHDRS {
23
        phdr            PT_PHDR         FLAGS(4) PHDRS;
24
        load            PT_LOAD         FLAGS(7) FILEHDR PHDRS;
25
        dynamic         PT_DYNAMIC      FLAGS(4);
26
        eh_frame_hdr    PT_GNU_EH_FRAME;
27
        note            PT_NOTE         FLAGS(4);
28
}
29

30
SECTIONS {
31
        /*
32
         * We can't prelink to any address without knowing something about
33
         * the virtual memory space of the host, since that leaks over into
34
         * the available memory space of the guest.
35
         */
36
        . = SIZEOF_HEADERS;
37

38
        /*
39
         * The following, including the FILEHDRS and PHDRS, are modified
40
         * when we relocate the binary.  We want them to be initially
41
         * writable for the relocation; we'll force them read-only after.
42
         */
43
        .note           : { *(.note*) }         :load :note
44
        .dynamic        : { *(.dynamic) }       :load :dynamic
45
        .dynsym         : { *(.dynsym) }        :load
46
        /*
47
         * There ought not be any real read-write data.
48
         * But since we manipulated the segment layout,
49
         * we have to put these sections somewhere.
50
         */
51
        .data           : {
52
                *(.data*)
53
                *(.sdata*)
54
                *(.got.plt) *(.got)
55
                *(.gnu.linkonce.d.*)
56
                *(.bss*)
57
                *(.dynbss*)
58
                *(.gnu.linkonce.b.*)
59
        }
60

61
        .rodata         : { *(.rodata*) }
62
        .hash           : { *(.hash) }
63
        .gnu.hash       : { *(.gnu.hash) }
64
        .dynstr         : { *(.dynstr) }
65
        .gnu.version    : { *(.gnu.version) }
66
        .gnu.version_d  : { *(.gnu.version_d) }
67
        .gnu.version_r  : { *(.gnu.version_r) }
68
        .eh_frame_hdr   : { *(.eh_frame_hdr) }  :load :eh_frame_hdr
69
        .eh_frame       : { *(.eh_frame) }      :load
70

71
        .text           : { *(.text*) }         :load   =0xd503201f
72
}
73