proj/qml/Main.qml - dev - v-str/cerera_android

proj/qml/Main.qml
76 строк2 KB
v-str
Dashboard: вёрстка по описанию + Q_PROPERTY заглушки + Components модуль
04 июл 2026, 19:25
04 июл 2026, 19:25b8ed9f4
import QtQuick
import QtQuick.Controls

import "screens"

ApplicationWindow {
    color: SpaceMill.spaceBg

    font.family: "Source Code Pro"
    font.weight: Font.ExtraLight
    palette.windowText: SpaceMill.spaceText

    title: "MillSim client"
    visible: true
    width: 360
    height: 640

    Image {
        anchors.fill: parent
        source: "images/CNC_TechDraw_Main.png"
        fillMode: Image.PreserveAspectCrop
        opacity: 0.2
    }

    StackView {
        id: stackView
        anchors.fill: parent
        initialItem: connectionScreenComponent
        clip: true

        pushEnter: Transition {
            ParallelAnimation {
                NumberAnimation { property: "y"; from: stackView.height; to: 0; duration: 700; easing.type: Easing.OutCubic }
                NumberAnimation { property: "opacity"; from: 0.0; to: 1.0; duration: 700 }
            }
        }
        pushExit: Transition {
            ParallelAnimation {
                NumberAnimation { property: "y"; from: 0; to: -stackView.height; duration: 700; easing.type: Easing.OutCubic }
                NumberAnimation { property: "opacity"; from: 1.0; to: 0.0; duration: 600 }
            }
        }
        popEnter: Transition {
            ParallelAnimation {
                NumberAnimation { property: "y"; from: -stackView.height; to: 0; duration: 700; easing.type: Easing.OutCubic }
                NumberAnimation { property: "opacity"; from: 0.0; to: 1.0; duration: 600 }
            }
        }
        popExit: Transition {
            ParallelAnimation {
                NumberAnimation { property: "y"; from: 0; to: stackView.height; duration: 700; easing.type: Easing.OutCubic }
                NumberAnimation { property: "opacity"; from: 1.0; to: 0.0; duration: 600 }
            }
        }
    }

    Connections {
        target: AppCore
        function onIsConnectedChanged() {
            if (AppCore.isConnected)
                stackView.push(dashboardComponent)
            else
                stackView.pop()
        }
    }

    Component {
        id: connectionScreenComponent
        ConnectionScreen {}
    }

    Component {
        id: dashboardComponent
        Dashboard {}
    }
}