proj/qml/Components/AppButton.qml - dev - v-str/cerera_android

proj/qml/Components/AppButton.qml
113 строк3 KB
v-str
Dashboard: вёрстка по описанию + Q_PROPERTY заглушки + Components модуль
04 июл 2026, 19:25
04 июл 2026, 19:25b8ed9f4
import QtQuick
import QtQuick.Controls

Button {
    id: control

    readonly property int normal: 0
    readonly property int warning: 1
    readonly property int error: 2

    property int colorType: normal
    property int clickDelay: 280

    signal delayedClick()

    Timer {
        id: clickTimer
        interval: control.clickDelay
        repeat: false
        onTriggered: control.delayedClick()
    }

    onClicked: clickTimer.restart()

    leftPadding: 15
    rightPadding: 15
    topPadding: 15
    bottomPadding: 15
    font.pixelSize: 20

    transform: Translate { id: pressTransform }

    onPressedChanged: {
        if (pressed) {
            releaseSeq.stop()
            waveRect.x = -waveRect.width
            pressTo.start()
        } else {
            pressTo.stop()
            releaseSeq.start()
        }
    }

    PropertyAnimation {
        id: pressTo
        target: pressTransform
        properties: "x,y"
        to: 2
        duration: 60
    }

    SequentialAnimation {
        id: releaseSeq
        PropertyAnimation {
            target: pressTransform
            properties: "x,y"
            to: 0
            duration: 60
        }
        PropertyAnimation {
            target: waveRect
            property: "x"
            from: -waveRect.width
            to: waveRect.parent.width
            duration: 150
        }
    }

    function borderColor() {
        if (!control.enabled)
            return "transparent"
        switch (control.colorType) {
        case warning: return SpaceMill.spaceWarning
        case error:   return SpaceMill.spaceError
        default:      return SpaceMill.spaceSuccess
        }
    }

    function fgColor() {
        if (!control.enabled)
            return SpaceMill.spaceTextMuted
        switch (control.colorType) {
        case warning: return SpaceMill.spaceWarning
        case error:   return SpaceMill.spaceError
        default:      return SpaceMill.spaceSuccess
        }
    }

    background: Rectangle {
        id: bg
        radius: 5
        color: SpaceMill.spaceElement
        border.width: 0.5
        border.color: borderColor()
        clip: true

        Rectangle {
            id: waveRect
            width: parent.width * 0.4
            height: parent.height
            color: Qt.rgba(1, 1, 1, 0.12)
            x: -width
        }
    }

    contentItem: Text {
        text: control.text
        font: control.font
        color: fgColor()
        horizontalAlignment: Text.AlignHCenter
        verticalAlignment: Text.AlignVCenter
    }
}