keepassxc

1
# The MIT License (MIT)
2
#
3
# Copyright (c) 2015, by [halex2005](mailto:akharlov@gmail.com)
4
#
5
# Permission is hereby granted, free of charge, to any person obtaining a copy of
6
# this software and associated documentation files (the "Software"), to deal in
7
# the Software without restriction, including without limitation the rights to
8
# use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
9
# the Software, and to permit persons to whom the Software is furnished to do so,
10
# subject to the following conditions:
11
#
12
# The above copyright notice and this permission notice shall be included in all
13
# copies or substantial portions of the Software.
14
#
15
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
16
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
17
# FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
18
# COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
19
# IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
20
# CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21

22

23
include (CMakeParseArguments)
24

25
set (GenerateProductVersionCurrentDir ${CMAKE_CURRENT_LIST_DIR})
26

27
# generate_product_version() function
28
#
29
# This function uses VersionInfo.in template file and VersionResource.rc file
30
# to generate WIN32 resource with version information and general resource strings.
31
#
32
# Usage:
33
#   generate_product_version(
34
#     SomeOutputResourceVariable
35
#     NAME MyGreatProject
36
#     ICON ${PATH_TO_APP_ICON}
37
#     VERSION_MAJOR 2
38
#     VERSION_MINOR 3
39
#     VERSION_PATH ${BUILD_COUNTER}
40
#     VERSION_REVISION ${BUILD_REVISION}
41
#   )
42
# where BUILD_COUNTER and BUILD_REVISION could be values from your CI server.
43
#
44
# You can use generated resource for your executable targets:
45
#   add_executable(target-name ${target-files} ${SomeOutputResourceVariable})
46
#
47
# You can specify resource strings in arguments:
48
#   NAME               - name of executable (no defaults, ex: Microsoft Word)
49
#   BUNDLE             - bundle (${NAME} is default, ex: Microsoft Office)
50
#   VERSION_MAJOR      - 1 is default
51
#   VERSION_MINOR      - 0 is default
52
#   VERSION_PATCH      - 0 is default
53
#   COMPANY_NAME       - your company name (no defaults)
54
#   COMPANY_COPYRIGHT  - ${COMPANY_NAME} (C) Copyright ${CURRENT_YEAR} is default
55
#   COMMENTS           - ${NAME} v${VERSION_MAJOR}.${VERSION_MINOR} is default
56
#   ORIGINAL_FILENAME  - ${NAME} is default
57
#   INTERNAL_NAME      - ${NAME} is default
58
#   FILE_DESCRIPTION   - ${NAME} is default
59
function(generate_product_version outfiles)
60
    set (options)
61
    set (oneValueArgs
62
        NAME
63
        BUNDLE
64
        VERSION_MAJOR
65
        VERSION_MINOR
66
        VERSION_PATCH
67
        COMPANY_NAME
68
        COMPANY_COPYRIGHT
69
        COMMENTS
70
        ORIGINAL_FILENAME
71
        INTERNAL_NAME
72
        FILE_DESCRIPTION)
73
    set (multiValueArgs)
74
    cmake_parse_arguments(PRODUCT "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
75

76
    if (NOT PRODUCT_BUNDLE OR "${PRODUCT_BUNDLE}" STREQUAL "")
77
        set(PRODUCT_BUNDLE "${PRODUCT_NAME}")
78
    endif()
79
    if (NOT PRODUCT_VERSION_MAJOR OR "${PRODUCT_VERSION_MAJOR}" STREQUAL "")
80
        set(PRODUCT_VERSION_MAJOR 1)
81
    endif()
82
    if (NOT PRODUCT_VERSION_MINOR OR "${PRODUCT_VERSION_MINOR}" STREQUAL "")
83
        set(PRODUCT_VERSION_MINOR 0)
84
    endif()
85
    if (NOT PRODUCT_VERSION_PATCH OR "${PRODUCT_VERSION_PATCH}" STREQUAL "")
86
        set(PRODUCT_VERSION_PATCH 0)
87
    endif()
88

89
    if (NOT PRODUCT_COMPANY_COPYRIGHT OR "${PRODUCT_COMPANY_COPYRIGHT}" STREQUAL "")
90
        string(TIMESTAMP PRODUCT_CURRENT_YEAR "%Y")
91
        set(PRODUCT_COMPANY_COPYRIGHT "Copyright (C) ${PRODUCT_CURRENT_YEAR} ${PRODUCT_COMPANY_NAME}")
92
    endif()
93
    if (NOT PRODUCT_COMMENTS OR "${PRODUCT_COMMENTS}" STREQUAL "")
94
        set(PRODUCT_COMMENTS "${PRODUCT_NAME} v${PRODUCT_VERSION_MAJOR}.${PRODUCT_VERSION_MINOR}.${PRODUCT_VERSION_PATCH}")
95
    endif()
96
    if (NOT PRODUCT_ORIGINAL_FILENAME OR "${PRODUCT_ORIGINAL_FILENAME}" STREQUAL "")
97
        set(PRODUCT_ORIGINAL_FILENAME "${PRODUCT_NAME}")
98
    endif()
99
    if (NOT PRODUCT_INTERNAL_NAME OR "${PRODUCT_INTERNAL_NAME}" STREQUAL "")
100
        set(PRODUCT_INTERNAL_NAME "${PRODUCT_NAME}")
101
    endif()
102
    if (NOT PRODUCT_FILE_DESCRIPTION OR "${PRODUCT_FILE_DESCRIPTION}" STREQUAL "")
103
        set(PRODUCT_FILE_DESCRIPTION "${PRODUCT_NAME}")
104
    endif()
105

106
    set (_VersionInfoFile ${CMAKE_CURRENT_BINARY_DIR}/VersionInfo.h)
107
    set (_VersionResourceFile ${CMAKE_CURRENT_BINARY_DIR}/VersionResource.rc)
108
    configure_file(
109
        ${GenerateProductVersionCurrentDir}/VersionInfo.in
110
        ${_VersionInfoFile}
111
        @ONLY)
112
    configure_file(
113
        ${GenerateProductVersionCurrentDir}/VersionResource.rc
114
        ${_VersionResourceFile}
115
        COPYONLY)
116
    list(APPEND ${outfiles} ${_VersionInfoFile} ${_VersionResourceFile})
117
    set (${outfiles} ${${outfiles}} PARENT_SCOPE)
118
endfunction()
119