build.gradle - develop - rixy/incubator__java

build.gradle
80 строк2 KB
rixy
10 ноя 2025, 21:20
10 ноя 2025, 21:20b8de7a1
plugins {
    id "java-library"
    alias libs.plugins.io.spring.dependency.management
    alias libs.plugins.net.ltgt.errorprone
    alias libs.plugins.org.springframework.boot
}

import net.ltgt.gradle.errorprone.CheckSeverity
import net.ltgt.gradle.errorprone.ErrorProneOptions

subprojects {

    apply plugin: "java-library"
    apply plugin: "io.spring.dependency-management"
    apply plugin: "org.springframework.boot"

    dependencies {

        // ↓↓↓ lombok ↓↓↓
        annotationProcessor "org.projectlombok:lombok"
        testAnnotationProcessor "org.projectlombok:lombok"
        implementation "org.projectlombok:lombok"
        // ↑↑↑ lombok ↑↑↑

        implementation "com.fasterxml.jackson.core:jackson-databind"
        implementation "jakarta.annotation:jakarta.annotation-api"

    }

    final testFramework = project(":test_framework")
    if (project == testFramework) {
        // noop
    } else {
        apply plugin: "net.ltgt.errorprone"
        dependencies {
            // ↓↓↓ static analysis ↓↓↓
            errorprone libs.com.uber.nullaway.nullaway
            errorprone libs.com.google.errorprone.error.prone.core
            // ↑↑↑ static analysis ↑↑↑
            testImplementation testFramework
        }
        tasks.withType(JavaCompile).configureEach {
            options.errorprone { ErrorProneOptions opts ->

                opts.disableWarningsInGeneratedCode = true

                // https://github.com/uber/NullAway/wiki/Configuration
                opts.check("NullAway", CheckSeverity.ERROR)
                opts.option("NullAway:AnnotatedPackages", "ru.gitverse.rixy")
                opts.option("NullAway:ExcludedClassAnnotations", ""
                        + "jakarta.annotation.Generated,"
                )
                opts.option("NullAway:ExcludedFieldAnnotations", ""
                        + "org.mockito.InjectMocks,"
                        + "org.mockito.Mock,"
                        + "org.mockito.Spy,"
                )

            }
        }
    }

    jar {
        archiveClassifier.set ""
    }

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
            vendor = JvmVendorSpec.ADOPTIUM
        }
        withSourcesJar()
        withJavadocJar()
    }

    test {
        useJUnitPlatform()
    }

}