yuzu

1
# SPDX-FileCopyrightText: 2023 yuzu Emulator Project
2
# SPDX-License-Identifier: GPL-2.0-or-later
3

4
set(ZONE_PATH ${CMAKE_ARGV3})
5
set(HEADER_NAME ${CMAKE_ARGV4})
6
set(NX_TZDB_INCLUDE_DIR ${CMAKE_ARGV5})
7
set(NX_TZDB_SOURCE_DIR ${CMAKE_ARGV6})
8

9
execute_process(
10
    COMMAND ${CMAKE_COMMAND} -P ${NX_TZDB_SOURCE_DIR}/ListFilesInDirectory.cmake
11
    WORKING_DIRECTORY ${ZONE_PATH}
12
    OUTPUT_VARIABLE FILE_LIST)
13

14
if (NOT FILE_LIST)
15
    message(FATAL_ERROR "No timezone files found in directory ${ZONE_PATH}, did the download fail?")
16
endif()
17

18
set(DIRECTORY_NAME ${HEADER_NAME})
19

20
set(FILE_DATA "")
21
foreach(ZONE_FILE ${FILE_LIST})
22
    if (ZONE_FILE STREQUAL "\n")
23
        continue()
24
    endif()
25

26
    string(APPEND FILE_DATA "{\"${ZONE_FILE}\",\n{")
27

28
    file(READ ${ZONE_PATH}/${ZONE_FILE} ZONE_DATA HEX)
29
    string(LENGTH "${ZONE_DATA}" ZONE_DATA_LEN)
30
    foreach(I RANGE 0 ${ZONE_DATA_LEN} 2)
31
        math(EXPR BREAK_LINE "(${I} + 2) % 38")
32

33
        string(SUBSTRING "${ZONE_DATA}" "${I}" 2 HEX_DATA)
34
        if (NOT HEX_DATA)
35
            break()
36
        endif()
37

38
        string(APPEND FILE_DATA "0x${HEX_DATA},")
39
        if (BREAK_LINE EQUAL 0)
40
            string(APPEND FILE_DATA "\n")
41
        else()
42
            string(APPEND FILE_DATA " ")
43
        endif()
44
    endforeach()
45

46
    string(APPEND FILE_DATA "}},\n")
47
endforeach()
48

49
file(READ ${NX_TZDB_SOURCE_DIR}/tzdb_template.h.in NX_TZDB_TEMPLATE_H_IN)
50
file(CONFIGURE OUTPUT ${NX_TZDB_INCLUDE_DIR}/nx_tzdb/${HEADER_NAME}.h CONTENT "${NX_TZDB_TEMPLATE_H_IN}")
51