src/sysupdate/meson.build - main - niceSOFT/systemd

src/sysupdate/meson.build
72 строки2 KB
Lennart Poettering
sysupdate: generalize feature name validity check
10 июл 2026, 15:37
10 июл 2026, 15:37d298f9b
# SPDX-License-Identifier: LGPL-2.1-or-later

systemd_sysupdate_sources = files(
        'sysupdate-cache.c',
        'sysupdate-cleanup.c',
        'sysupdate-config.c',
        'sysupdate-feature.c',
        'sysupdate-instance.c',
        'sysupdate-partition.c',
        'sysupdate-pattern.c',
        'sysupdate-resource.c',
        'sysupdate-target.c',
        'sysupdate-transfer.c',
        'sysupdate-update-set.c',
        'sysupdate.c',
)
systemd_sysupdate_export_sources = files(
        'sysupdate-update-set-flags.c',
        'sysupdate-util.c',
)

systemd_updatectl_sources = files(
        'updatectl.c',
)

executables += [
        executable_template + {
                'name' : 'systemd-sysupdate',
                'public' : true,
                'conditions' : ['ENABLE_SYSUPDATE'],
                'sources' : systemd_sysupdate_sources,
                'export' : systemd_sysupdate_export_sources,
                'dependencies' : [
                        libfdisk_cflags,
                        libopenssl_cflags,
                ],
        },
        libexec_template + {
                'name' : 'systemd-sysupdated',
                'dbus' : true,
                'conditions' : ['ENABLE_SYSUPDATED'],
                'sources' : files('sysupdated.c', 'sysupdate-target.c', 'sysupdate-util.c'),
        },
        executable_template + {
                'name' : 'updatectl',
                'public' : true,
                'sources' : systemd_updatectl_sources,
                'import' : ['systemd-sysupdate'],
                'conditions' : ['ENABLE_SYSUPDATED'],
        },
        test_template + {
                'sources' : files('test-sysupdate-util.c'),
                'import' : ['systemd-sysupdate'],
                'conditions' : ['ENABLE_SYSUPDATE'],
        },
]

if conf.get('ENABLE_SYSUPDATED') == 1
        install_data('org.freedesktop.sysupdate1.conf',
                     install_dir : dbuspolicydir)
        install_data('org.freedesktop.sysupdate1.service',
                     install_dir : dbussystemservicedir)
        install_data('org.freedesktop.sysupdate1.policy',
                     install_dir : polkitpolicydir)
endif

if conf.get('ENABLE_SYSUPDATE') == 1
        # symlink for backwards compatibility after rename
        install_symlink('systemd-sysupdate',
                        pointing_to : libexecdir_to_bin / 'systemd-sysupdate',
                        install_dir : libexecdir)
endif