ru_tts
/
configure.ac
54 строки · 1.9 Кб
1# Process this file with autoconf to produce a configure script.
2
3AC_PREREQ(2.69)
4
5AC_INIT([ru-tts], [6.2.3])
6AC_CONFIG_SRCDIR([src/ru_tts.c])
7AC_CONFIG_HEADERS([src/config.h])
8AC_CONFIG_MACRO_DIRS([m4])
9AM_INIT_AUTOMAKE([foreign])
10LT_INIT
11
12# Guess environment.
13AC_CANONICAL_HOST
14AC_CANONICAL_BUILD
15
16# Checks for programs.
17AC_PROG_CC
18AC_PROG_CPP
19AC_PROG_INSTALL
20
21# Language choice.
22AC_LANG([C])
23AX_CHECK_VSCRIPT
24
25# Checks for typedefs, structures, and compiler characteristics.
26AC_TYPE_SIZE_T
27
28# Checks for required headers and libraries.
29AC_CHECK_HEADERS([stdint.h stdlib.h unistd.h string.h stdio.h fcntl.h math.h limits.h sys/types.h sys/stat.h], [],
30[AC_MSG_ERROR([Some system header files are not found])])
31AC_SEARCH_LIBS([rint], [m], [], [AC_MSG_ERROR([The rint() function is unavailable])])
32
33# Cooperation with the Rulex pronunciation dictionary
34AC_ARG_WITH([dictionary],
35AS_HELP_STRING([--with-dictionary],
36[whether to link with the rulex library to take advantage of the pronunciation dictionary
37(by default the library is not linked in but dlopened at runtime).]))
38
39AS_IF([test "x$with_dictionary" = "xyes"], [
40CHECK_FOR_LOCALES_SUPPORT
41AC_CHECK_HEADER([rulexdb.h], [], [AC_MSG_ERROR([Header file rulexdb.h is not found])])
42AC_SEARCH_LIBS([rulexdb_search], [rulexdb], [], [AC_MSG_ERROR([Broken or unavailable rulexdb library])])
43], [test "x$with_dictionary" != "xno"], [
44CHECK_FOR_LOCALES_SUPPORT
45AC_CHECK_HEADER([dlfcn.h], [], [AC_MSG_ERROR([Header file dlfcn.h is not found])])
46AC_SEARCH_LIBS([dlopen], [dl], [], [AC_MSG_ERROR([The dlopen() function is unavailable])])
47AC_DEFINE([RULEX_DLL], ["librulexdb.so.0"], [RuLex DLL])
48], [
49AC_DEFINE([WITHOUT_DICTIONARY], [], [Drop RuLex dictionary support])
50])
51
52# Output results.
53AC_CONFIG_FILES([Makefile src/Makefile manpages/Makefile])
54AC_OUTPUT
55