flake.nix - master - igsha/dotfiles

flake.nix
63 строки2 KB
Igor Sharonov
users: Add uniplay
22 апр 2026, 22:32
22 апр 2026, 22:32c1d2d07
{
  description = "My NixOS configuration";

  inputs = {
    nixpkgs.url = github:nixos/nixpkgs?ref=nixos-unstable;
    nixos-hardware.url = github:nixos/nixos-hardware/master;
    home-config.url = github:igsha/home-config/main;
    #hyprland.url = github:hyprwm/Hyprland;
    yt-dlp-plugins = {
      url = github:igsha/yt-dlp-plugins/master;
      inputs.nixpkgs.follows = "nixpkgs";
    };
    tmux-mycollection = {
      url = github:igsha/tmux-mycollection/main;
      inputs.nixpkgs.follows = "nixpkgs";
    };
    uniplay = {
      url = github:igsha/uniplay/main;
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, nixos-hardware, home-config, ... }@inputs:
    let
      system = "x86_64-linux";
      defaults = { pkgs, lib, ... }: {
        system.configurationRevision = self.rev or self.dirtyRev or "dirty";
        nixpkgs.overlays = [
          inputs.yt-dlp-plugins.overlays.default
          inputs.tmux-mycollection.overlays.default
          (import ./overlays.nix)
          (final: prev: {
            uniplay = inputs.uniplay.packages.${prev.system}.default;
          })
        ];
        nix = {
          registry = builtins.mapAttrs (k: v: {
            to = {
              type = "path";
              path = v.outPath;
            };
          }) (builtins.removeAttrs inputs [ "self" ]);
          package = pkgs.nixVersions.latest;
        };
        home-config-basedir = lib.mkForce ./.;
      };
      filterDirs = nixpkgs.lib.attrsets.filterAttrs (k: v: v == "directory");
      machines = filterDirs (builtins.readDir ./machines);
      configurateMachine = k: v: nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = inputs;
        modules = [
          home-config.nixosModules.default
          defaults
          #inputs.hyprland.nixosModules.default
          ./machines/${k}
        ];
      };

    in {
      nixosConfigurations = builtins.mapAttrs configurateMachine machines;
    };
}