code/modules/spells/targeted/targeted.dm - Bleeding-Edge - githubmirror/vgstation13

code/modules/spells/targeted/targeted.dm
216 строк7 KB
DeityLink
Fixed instant blindness + Adjusted eye_blind values across the board to account for the new behaviour (#38871)
10 янв 2026, 23:27
10 янв 2026, 23:27816051f
/*
Targeted spells (with the exception of dumbfire) select from all the mobs in the defined range
Targeted spells have two useful flags: INCLUDEUSER and SELECTABLE. These are explained in setup.dm
*/


/spell/targeted //can mean aoe for mobs (limited/unlimited number) or one target mob
	spell_flags = SELECTABLE
	user_type = USER_TYPE_NOUSER
	valid_targets = list()
	var/max_targets = 1 //leave 0 for unlimited targets in range, more for limited number of casts (can all target one guy, depends on target_ignore_prev) in range
	var/target_ignore_prev = 1 //only important if max_targets > 1, affects if the spell can be cast multiple times at one person from one cast


	var/amt_knockdown = 0
	var/amt_paralysis = 0
	var/amt_stunned = 0

	var/amt_dizziness = 0
	var/amt_confused = 0
	var/amt_stuttering = 0

		//set to negatives for healing
	var/amt_dam_fire = 0
	var/amt_dam_brute = 0
	var/amt_dam_oxy = 0
	var/amt_dam_tox = 0
	var/amt_dam_brain = 0

	var/amt_eye_blind = 0
	var/amt_eye_blurry = 0
	var/mind_affecting = 0 //Determines if it can be blocked by PSY_RESIST or tinfoil hat

/spell/targeted/is_valid_target(atom/target, mob/user, options, bypass_range = 0)
	if(!(spell_flags & INCLUDEUSER) && target == user)
		return 0
	if(!(range == GLOBALCAST) && !bypass_range && !(range == SELFCAST && target == user) && (options && !(target in options))) //Shouldn't be necessary but a good check in case of overrides
		return 0
	if(ismob(target))
		var/mob/M = target
		if (mind_affecting && !user.can_mind_interact(M.mind))
			return 0
		if(user in M.get_arcane_golems())
			return 0
		if(user.shares_arcane_golem_spell(M))
			return 0
	return !valid_targets.len || is_type_in_list(target, valid_targets)

/spell/targeted/choose_targets(mob/user = usr)
	if(mind_affecting && tinfoil_check(user))
		to_chat(user, "<span class='warning'>Something is interfering with your ability to target minds.</span>")
		return
	var/list/targets = list()
	if(max_targets == 0) //unlimited
		if(range == -2)
			targets = living_mob_list
		else
			for(var/mob/living/target in view_or_range(range, holder, selection_type))
				targets += target

	else if(max_targets == 1) //single target can be picked
		if(spell_flags & TALKED_BEFORE)
			if(!user || !user.mind || !user.mind.heard_before.len)
				return
			var/list/possible_targets = user.mind.heard_before.Copy()
			if(ismushroom(user) && istype(src, /spell/targeted/telepathy))
				possible_targets += "Local"
				var/spell/targeted/telepathy/telepathy = src
				telepathy.telepathy_type = SPECIFIC_TELEPATHY
			possible_targets += "All"
			if(spell_flags & INCLUDEUSER)
				possible_targets[user.real_name] = user.mind
			var/target_name = input(user, "Choose the target, from those whose voices you've heard before.", "Targeting") as null|anything in possible_targets
			if(isnull(target_name))
				return
			var/datum/mind/temp_target
			if(target_name == "All")
				if(ismushroom(user) && istype(src, /spell/targeted/telepathy))
					var/spell/targeted/telepathy/telepathy = src
					telepathy.telepathy_type = GLOBAL_TELEPATHY
				for(var/T in possible_targets)
					if(T == "All" || T == "Local")
						continue
					temp_target = possible_targets[T]
					targets += temp_target.current
			else if(target_name == "Local")
				if(ismushroom(user) && istype(src, /spell/targeted/telepathy))
					var/spell/targeted/telepathy/telepathy = src
					telepathy.telepathy_type = LOCAL_TELEPATHY
				for(var/T in possible_targets)
					if (T == "All" || T == "Local")
						continue
					temp_target = possible_targets[T]
					targets += temp_target.current
			else
				temp_target = possible_targets[target_name]
				targets += temp_target.current
		else if((range == 0 || range == SELFCAST) && (spell_flags & INCLUDEUSER))
			targets += user
		else
			var/list/possible_targets = list()
			var/list/starting_targets
			if(range == GLOBALCAST)
				starting_targets = living_mob_list
			else
				starting_targets = view_or_range(range, holder, selection_type)

			for(var/mob/living/M in starting_targets)
				if(!(spell_flags & INCLUDEUSER) && M == user)
					continue
				if(valid_targets && valid_targets.len)
					if(!is_type_in_list(M, valid_targets))
						continue
				if(valid_targets && valid_targets.len && !is_type_in_list(M, valid_targets))
					continue
				if(mind_affecting)
					if(iscarbon(user))
						if(!M.mind || !user.can_mind_interact(M.mind))
							continue
				possible_targets += M

			if(possible_targets.len)
				if(spell_flags & SELECTABLE) //if we are allowed to choose. see setup.dm for details
					var/mob/temp_target = input(user, "Choose the target for the spell.", "Targeting") as null|mob in possible_targets
					if(temp_target)
						targets += temp_target
				else
					targets += pick(possible_targets)
			//Adds a safety check post-input to make sure those targets are actually in range.


	else
		var/list/possible_targets = list()
		var/list/starting_targets

		if(range == -2)
			starting_targets = living_mob_list
		else
			starting_targets = view_or_range(range, holder, selection_type)

		for(var/mob/living/target in starting_targets)
			if(!(spell_flags & INCLUDEUSER) && target == user)
				continue
			if(valid_targets && !is_type_in_list(target, valid_targets))
				continue
			possible_targets += target

		if(spell_flags & SELECTABLE)
			for(var/i = 1; i<=max_targets; i++)
				if(!possible_targets.len)
					break
				var/mob/M = input(user, "Choose the target for the spell.", "Targeting") as null|mob in possible_targets
				if(!M)
					break
				if(range != -2)
					if(!(M in view_or_range(range, holder, selection_type)))
						continue
				targets += M
				possible_targets -= M
		else
			for(var/i=1,i<=max_targets,i++)
				if(!possible_targets.len)
					break
				if(target_ignore_prev)
					var/target = pick(possible_targets)
					possible_targets -= target
					targets += target
				else
					targets += pick(possible_targets)

	if(!(spell_flags & INCLUDEUSER) && (user in targets))
		targets -= user

	if(valid_targets && valid_targets.len)
		for(var/mob/living/target in targets) //filters out all the non-compatible mobs
			if(!is_type_in_list(target, valid_targets))
				targets -= target

	return targets

/spell/targeted/cast(var/list/targets, mob/user)
	for(var/mob/living/target in targets)
		if(range >= 0)
			if(!(target in view_or_range(range, holder, selection_type))) //filter at time of casting
				targets -= target
				continue
		apply_spell_damage(target)

/spell/targeted/proc/apply_spell_damage(mob/living/target)
	target.adjustBruteLoss(amt_dam_brute)
	target.adjustFireLoss(amt_dam_fire)
	target.adjustToxLoss(amt_dam_tox)
	target.adjustOxyLoss(amt_dam_oxy)
	target.adjustBrainLoss(amt_dam_brain)
	//disabling
	target.AdjustKnockdown(amt_knockdown)
	target.AdjustParalysis(amt_paralysis)
	target.AdjustStunned(amt_stunned)
	if(amt_knockdown || amt_paralysis || amt_stunned)
		target.unlock_from()
	if (amt_eye_blind > 0)
		target.instant_blindness(amt_eye_blind)
	target.eye_blurry += amt_eye_blurry
	target.dizziness += amt_dizziness
	target.confused += amt_confused
	target.confused_intensity = CONFUSED_MAGIC
	target.stuttering += amt_stuttering

/spell/targeted/proc/tinfoil_check(mob/living/carbon/human/user)
	if(!istype(user))
		return 0

	if(user.is_wearing_any(list(/obj/item/clothing/head/tinfoil,/obj/item/clothing/head/helmet/stun), slot_head))
		return 1

	return 0