code/modules/events/brand_intelligence.dm - Bleeding-Edge - githubmirror/vgstation13

code/modules/events/brand_intelligence.dm

60 строк2 KB

DeityLink

Rampant Brand Intelligence random event tweaks (#36961)

25 авг 2024, 15:56

25 авг 2024, 15:56f51fd93

/datum/event/brand_intelligence
	announceWhen	= 30
	endWhen			= 900	//Ends when all vending machines are subverted anyway.
	oneShot			= 1

	var/list/obj/machinery/vending/vendingMachines = list()
	var/list/obj/machinery/vending/infectedVendingMachines = list()
	var/obj/machinery/vending/originMachine

/datum/event/brand_intelligence/can_start()
	return 30

/datum/event/brand_intelligence/announce()
	command_alert(/datum/command_alert/vending_machines)


/datum/event/brand_intelligence/start()
	for(var/obj/machinery/vending/V in machines)
		if(V.z != map.zMainStation)
			continue
		vendingMachines.Add(V)

	if(!vendingMachines.len)
		kill()
		return

	originMachine = pick(vendingMachines)
	vendingMachines.Remove(originMachine)
	originMachine.shut_up = 0
	originMachine.shoot_inventory = 1


/datum/event/brand_intelligence/tick()
	if(!vendingMachines.len || !originMachine || originMachine.shut_up)	//if every machine is infected, or if the original vending machine is missing or has it's voice switch flipped
		end()
		kill()
		return

	if(IsMultiple(activeFor, 5))
		if(prob(25))
			var/obj/machinery/vending/infectedMachine = pick(vendingMachines)
			vendingMachines.Remove(infectedMachine)
			infectedVendingMachines.Add(infectedMachine)
			infectedVendingMachines[infectedMachine] = infectedMachine.shut_up
			infectedMachine.shut_up = 0
			infectedMachine.shoot_inventory = 1

			originMachine.speak(pick("Try our aggressive new marketing strategies!", \
									 "You should buy products to feed your lifestyle obession!", \
									 "Consume!", \
									 "Your money can buy happiness!", \
									 "Engage direct marketing!", \
									 "Advertising is legalized lying! But don't let that put you off our great deals!", \
									 "You don't want to buy anything? Yeah, well I didn't want to buy your mom either."))

/datum/event/brand_intelligence/end()
	for(var/obj/machinery/vending/infectedMachine in infectedVendingMachines)
		infectedMachine.shut_up = infectedVendingMachines[infectedMachine]
		infectedMachine.shoot_inventory = 0
	command_alert(/datum/command_alert/vending_machines_end)