githubmirror/liburing

src/liburing.map
140 строк3 KB
Jens Axboe
Bump version to 2.14
17 дек 2025, 05:35
17 дек 2025, 05:35ad9cead
LIBURING_2.0 {
	global:
		io_uring_get_probe;
		io_uring_get_probe_ring;
		io_uring_free_probe;
		io_uring_get_sqe;
		io_uring_peek_batch_cqe;
		io_uring_queue_exit;
		io_uring_queue_init;
		io_uring_queue_init_params;
		io_uring_queue_mmap;
		io_uring_register_buffers;
		io_uring_register_eventfd;
		io_uring_register_eventfd_async;
		io_uring_register_files;
		io_uring_register_files_update;
		io_uring_register_personality;
		io_uring_register_probe;
		io_uring_ring_dontfork;
		io_uring_submit;
		io_uring_submit_and_wait;
		io_uring_unregister_buffers;
		io_uring_unregister_eventfd;
		io_uring_unregister_files;
		io_uring_unregister_personality;
		io_uring_wait_cqe_timeout;
		io_uring_wait_cqes;

		__io_uring_get_cqe;
		__io_uring_sqring_wait;
	local:
		*;
};

LIBURING_2.1 {
	global:
		io_uring_mlock_size_params;
		io_uring_mlock_size;
		io_uring_register_buffers_tags;
		io_uring_register_buffers_update_tag;
		io_uring_register_files_tags;
		io_uring_register_files_update_tag;
		io_uring_register_iowq_aff;
		io_uring_unregister_iowq_aff;
		io_uring_register_iowq_max_workers;
} LIBURING_2.0;

LIBURING_2.2 {
	global:
		io_uring_submit_and_wait_timeout;
		io_uring_register_ring_fd;
		io_uring_unregister_ring_fd;
		io_uring_register_files_sparse;
		io_uring_register_buffers_sparse;
		io_uring_register_buf_ring;
		io_uring_unregister_buf_ring;
} LIBURING_2.1;

LIBURING_2.3 {
	global:
		io_uring_register_sync_cancel;
		io_uring_register_file_alloc_range;
		io_uring_enter;
		io_uring_enter2;
		io_uring_setup;
		io_uring_register;
		io_uring_get_events;
		io_uring_submit_and_get_events;
} LIBURING_2.2;

LIBURING_2.4 {
	global:
		io_uring_major_version;
		io_uring_minor_version;
		io_uring_check_version;

		io_uring_close_ring_fd;
		io_uring_enable_rings;
		io_uring_register_restrictions;
		io_uring_setup_buf_ring;
		io_uring_free_buf_ring;
} LIBURING_2.3;

LIBURING_2.5 {
	global:
		io_uring_queue_init_mem;
} LIBURING_2.4;

LIBURING_2.6 {
	global:
		io_uring_buf_ring_head;
		io_uring_register_napi;
		io_uring_unregister_napi;
} LIBURING_2.5;

LIBURING_2.7 {
} LIBURING_2.6;

LIBURING_2.8 {
	global:
		io_uring_register_clock;
		io_uring_submit_and_wait_min_timeout;
		io_uring_wait_cqes_min_timeout;
		io_uring_clone_buffers;
} LIBURING_2.7;

LIBURING_2.9 {
		io_uring_resize_rings;
		io_uring_register_wait_reg;
		io_uring_submit_and_wait_reg;
		io_uring_clone_buffers_offset;
		io_uring_register_region;
} LIBURING_2.8;

LIBURING_2.10 {
	global:
		io_uring_register_ifq;
		io_uring_set_iowait;
		__io_uring_clone_buffers;
		__io_uring_clone_buffers_offset;
} LIBURING_2.9;

LIBURING_2.11 {
	global:
		io_uring_memory_size;
		io_uring_memory_size_params;
		io_uring_register_sync_msg;
} LIBURING_2.10;

LIBURING_2.12 {

} LIBURING_2.11;

LIBURING_2.13 {

} LIBURING_2.12;

LIBURING_2.14 {

} LIBURING_2.13;