githubmirror/libmodulemd

bindings/python/meson.build

30 строк915 B

Stephen Gallagher

Allow specifying the gobject overrides directory explicitly

08 апр 2020, 03:56

08 апр 2020, 03:56021ab08

gobject_overrides_dir_py3 = get_option('gobject_overrides_dir_py3')
gobject_overrides_dir_py2 = get_option('gobject_overrides_dir_py2')

# Python 3
if gobject_overrides_dir_py3 == ''
  ret = run_command([python3, '-c', 'import gi; print(gi._overridesdir)'])

  if ret.returncode() != 0
    error('Failed to determine Python 3 pygobject overridedir')
  else
    gobject_overrides_dir_py3 = ret.stdout().strip()
  endif
endif

install_data('gi/overrides/Modulemd.py', install_dir: gobject_overrides_dir_py3)

# Python 2
if with_py2
  if gobject_overrides_dir_py2 == ''
    ret2 = run_command([python2, '-c', 'import gi; print(gi._overridesdir)'])

    if ret2.returncode() != 0
      error('Failed to determine Python 2 pygobject overridedir')
    else
      gobject_overrides_dir_py2 = ret2.stdout().strip()
    endif
  endif

  install_data('gi/overrides/Modulemd.py', install_dir: gobject_overrides_dir_py2)
endif