api/build.gradle - main - githubmirror/halo

api/build.gradle
150 строк4 KB
John Niang
chore: upgrade dependencies and Gradle wrapper (#10168)
23 июл 2026, 13:45
23 июл 2026, 13:45642692e
plugins {
    id 'java-library'
    id 'halo.publish'
    id 'jacoco'
    alias(libs.plugins.lombok)
    alias(libs.plugins.versions)
    alias(libs.plugins.spotless)
}

group = 'run.halo.app'
description = 'API of halo project, connecting by other projects.'

tasks.withType(JavaCompile).configureEach {
    options.release = 21
    options.encoding = 'UTF-8'
}

tasks.withType(Javadoc).configureEach {
    options.encoding = 'UTF-8'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
    withJavadocJar()
    withSourcesJar()
}

jar {
    manifest {
        attributes(
                'Implementation-Title': project.name,
                'Implementation-Version': project.version,
                'Implementation-Vendor': 'Halo Project',
                )
    }
}

repositories {
    mavenCentral()
}

dependencies {
    api platform(project(':platform:application'))
    annotationProcessor platform(project(':platform:application'))

    // jspecify
    api 'org.jspecify:jspecify'

    api 'org.springframework.boot:spring-boot-starter-actuator'
    api 'org.springframework.boot:spring-boot-starter-mail'
    api 'org.springframework.boot:spring-boot-starter-thymeleaf'
    api 'org.springframework.boot:spring-boot-starter-webflux'
    api 'org.springframework.boot:spring-boot-starter-validation'
    api 'org.springframework.boot:spring-boot-starter-data-r2dbc'
    api 'org.springframework.session:spring-session-core'
    api 'org.springframework.boot:spring-boot-jackson2'
    api 'org.springframework.boot:spring-boot-integration'
    api 'org.springframework.boot:spring-boot-session'

    // Spring Security
    api 'org.springframework.boot:spring-boot-starter-security'
    api 'org.springframework.security:spring-security-oauth2-jose'
    api 'org.springframework.security:spring-security-oauth2-client'
    api 'org.springframework.security:spring-security-oauth2-resource-server'

    api 'io.micrometer:context-propagation'

    // Cache
    api "org.springframework.boot:spring-boot-starter-cache"
    api "com.github.ben-manes.caffeine:caffeine"

    api "org.springdoc:springdoc-openapi-starter-webflux-ui"
    api 'org.openapi4j:openapi-schema-validator'
    api "net.bytebuddy:byte-buddy"
    api "org.bouncycastle:bcpkix-jdk18on"

    // Apache Lucene
    api "org.apache.lucene:lucene-core"
    api "org.apache.lucene:lucene-queryparser"
    api "org.apache.lucene:lucene-highlighter"
    api "org.apache.lucene:lucene-backward-codecs"
    api 'org.apache.lucene:lucene-analysis-common'

    api "org.apache.commons:commons-lang3"
    api "io.seruco.encoding:base62"
    api "org.pf4j:pf4j"
    api "com.google.guava:guava"
    api "org.jsoup:jsoup"
    api "io.github.java-diff-utils:java-diff-utils"
    api "org.springframework.integration:spring-integration-core"
    api "com.github.java-json-tools:json-patch"
    api "org.thymeleaf.extras:thymeleaf-extras-springsecurity6"
    api 'org.apache.tika:tika-core'
    api 'net.coobird:thumbnailator'

    api "io.github.resilience4j:resilience4j-spring-boot4"
    api "io.github.resilience4j:resilience4j-reactor"

    api "com.j256.two-factor-auth:two-factor-auth"
    api 'com.github.ua-parser:uap-java'

    runtimeOnly 'io.r2dbc:r2dbc-h2'
    runtimeOnly 'org.postgresql:postgresql'
    runtimeOnly 'org.postgresql:r2dbc-postgresql'
    runtimeOnly 'org.mariadb:r2dbc-mariadb'
    runtimeOnly 'io.asyncer:r2dbc-mysql'
    runtimeOnly 'com.github.therapi:therapi-runtime-javadoc'

    annotationProcessor "com.github.therapi:therapi-runtime-javadoc-scribe"

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testImplementation 'io.projectreactor:reactor-test'

    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

publishing {
    publications.named('mavenJava', MavenPublication) {
        from components.java
        pom {
            name = 'API library'
            description = "$project.description"
        }
    }
}

tasks.named('test') {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
}

tasks.named('jacocoTestReport') {
    reports {
        xml.required = true
        html.required = false
    }
}

tasks.named('uploadBundle') {
    mustRunAfter project(':platform:application').tasks.named('uploadBundle')
}

spotless {
    java {
        palantirJavaFormat("2.90.0").formatJavadoc(true)
    }
}