githubmirror/FiraCode

clojure/regen_classes.clj

26 строк940 B

Nikita Prokopov

Old-style figures no longer prevent ligatures (closes #561 closes #715)

04 сен 2019, 12:47

04 сен 2019, 12:478edd007

;; clj -m regen-classes

(ns regen-classes
  (:require
    [clojure.string :as str]
    [glyphs :as glyphs]
    [flatland.ordered.map :refer [ordered-map]]))

(defn -main [& args]
  (let [path       (or (first args) "FiraCode.glyphs")
        font       (glyphs/load path)
        not-spaces (->> (:glyphs font)
                     (remove #(re-find #"^\.|space$|space\." (:glyphname %)))
                     (remove #(= "0" (:export %))))
        _          (println "Generating class:NotSpace with" (count not-spaces) "glyphs")
        class      (ordered-map
                     :code (str/join " " (map :glyphname not-spaces))
                     :name "NotSpace")
        classes    (->> (:classes font)
                     (remove #(= "NotSpace" (:name %)))
                     (cons class))
        font'      (assoc font :classes classes)
        _          (glyphs/save! path font')
        _          (println)]))

; (-main)