EvilBeaver/OneScript: Исполняющая среда скриптов на языке 1С

tests/array.os
91 строка4 KB
Mr-Rm
корректное создание массива заданной длины; рефакторинг
06 апр 2026, 10:58
06 апр 2026, 10:5863020bc
#Использовать asserts

///////////////////////////////////////////////////////////////////////
// Тест класса Массив
///////////////////////////////////////////////////////////////////////

Перем юТест;

////////////////////////////////////////////////////////////////////
// Программный интерфейс

Функция ПолучитьСписокТестов(ЮнитТестирование) Экспорт
	
	юТест = ЮнитТестирование;
	
	ВсеТесты = Новый Массив;
	
	ВсеТесты.Добавить("ТестДолжен_ПроверитьПоискВМассиве");
	ВсеТесты.Добавить("ТестДолжен_СоздатьМногомерныйМассив");
	ВсеТесты.Добавить("ТестДолжен_ПроверитьЗаписьВМногомерныйМассив");  // issue #1663
	ВсеТесты.Добавить("ТестДолжен_ПроверитьОшибкуРазмерности");
	
	Возврат ВсеТесты;
	
КонецФункции

Процедура ТестДолжен_ПроверитьПоискВМассиве() Экспорт
    
    Массив = Новый Массив();
    Массив.Добавить("1");
    Массив.Добавить("2");
    Массив.Добавить("3");

    Если Массив.Найти("1") <> Неопределено Тогда
        НашлиЗначение1 = Истина;
    Иначе
        НашлиЗначение1 = Ложь;
    КонецЕсли;

    Если Массив.Найти("9") <> Неопределено Тогда
        НашлиЗначение9 = Истина;
    Иначе
        НашлиЗначение9 = Ложь;
    КонецЕсли;
    
    юТест.ПроверитьРавенство(НашлиЗначение1, Истина, "Нашли 1");
    юТест.ПроверитьРавенство(НашлиЗначение9, Ложь, "Не нашли 9");
    юТест.ПроверитьРавенство(Массив.Найти("2"), 1, "Индекс элемента по значению");

КонецПроцедуры

Процедура ТестДолжен_СоздатьМногомерныйМассив() Экспорт

	Массив = Новый Массив(2,4,6,8);

	Ожидаем.Что(Массив.Количество(), "1-я размерность").Равно(2);
	Ожидаем.Что(Массив[0].Количество(), "2-я размерность").Равно(4);
	Ожидаем.Что(Массив[1][1].Количество(), "3-я размерность").Равно(6);
	Ожидаем.Что(Массив[1][1][2].Количество(), "4-я размерность").Равно(8);
	
КонецПроцедуры

Процедура ТестДолжен_ПроверитьЗаписьВМногомерныйМассив() Экспорт

	Массив = Новый Массив(3,3,3);
	Массив[0][0][0] = "Привет";
	Массив[1][0][0] = "Привет.";
	Массив[1][1][0] = "Привет!";
	Массив[2][0][0] = "Привет!!!";

	Ожидаем.Что(Массив[0][0][0]).Равно("Привет");
	Ожидаем.Что(Массив[1][0][0]).Равно("Привет.");
	Ожидаем.Что(Массив[1][1][0]).Равно("Привет!");
	Ожидаем.Что(Массив[2][0][0]).Равно("Привет!!!");
	Ожидаем.Что(Массив[2][1][0]).Равно(Неопределено);
	
КонецПроцедуры

Процедура ТестДолжен_ПроверитьОшибкуРазмерности() Экспорт

	Попытка
		Массив = Новый Массив(-1,-2,-3);
	Исключение
		Ошибка = ИнформацияОбОшибке().Описание;
		юТест.ПроверитьНеРавенство(Найти(Ошибка,"Неверное значение аргумента номер 1"), 0, "Неверный вид ошибки: "+Ошибка);  // не "номер 3"!
		Возврат;
	КонецПопытки;
	
	ВызватьИсключение "Должно было быть выдано исключение, но его не было";

КонецПроцедуры